home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib18.dsk / NOBOOT CREATOR.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  42 lines
  1. 10  REM  ***********************
  2. 20  REM  *   NOBOOT  CREATOR   *
  3. 30  REM  * BY BILL FORTENBERRY *
  4. 40  REM  * COPYRIGHT (C)  1983 *
  5. 50  REM  * BY MICROSPARC, INC. *
  6. 60  REM  * LINCOLN, MA.  01773 *
  7. 70  REM  ***********************
  8. 80  TEXT : HOME : VTAB 1: PRINT "****************************************": VTAB 10: PRINT "****************************************"
  9. 90  FOR I = 2 TO 9: VTAB I: PRINT "*                                      *": NEXT 
  10. 100  INVERSE :A$ = "+      +": VTAB 3: GOSUB 270: VTAB 5: GOSUB 270
  11. 110 A$ = " NOBOOT ": VTAB 4: GOSUB 270
  12. 120  NORMAL :A$ = "BY: BILL FORTENBERRY": VTAB 7: GOSUB 270:A$ = "COPYRIGHT 1983 BY MICROSPARC, INC.": VTAB 8: GOSUB 270
  13. 130  VTAB 12: PRINT "     THIS PROGRAM IS DESIGNED TO BE RUN": PRINT "AS AN ADDITION TO TONY DAHBURA'S DOS": PRINT "REMOVER (NIBBLE VOL 2,NO 8)."
  14. 140  PRINT : PRINT "     THE DOS REMOVER ALLOWS YOU TO USE": PRINT "TRACKS 1 AND 2 FOR DATA STORAGE (DOS ": PRINT "NORMALLY RESIDES HERE).  THIS PROGRAM": PRINT "PREVENTS A CRASH DURING BOOTING SINCE": PRINT "DOS ISN'T ON THE DISK ANY MORE."
  15. 150  PRINT : INPUT "PRESS RETURN ";A$
  16. 160  HOME :A$ = "INSTRUCTIONS": GOSUB 270: PRINT : PRINT "1.  RUN THE DOS REMOVER  (NOW THERE IS      NO DOS ON THE DISKETTE AND IT WILL      NOT BOOT)."
  17. 170  PRINT : PRINT "2.  RUN NOBOOT LOADER  (THE DISKETTE        STILL WON'T BOOT BUT IT NOW IT TELLS     YOU WHAT HAPPENS AND WHAT TO DO)."
  18. 180  PRINT : PRINT "     YOU CAN PUT DOS BACK ON A DISK": PRINT "WITH THE MASTER CREATE PROGRAM ON THE": PRINT "SYSTEM MASTER DISK."
  19. 190  PRINT : FLASH :A$ = "WARNING": GOSUB 270: NORMAL : PRINT : PRINT "     IF YOU HAVE SAVED ANY FILES SINCE": PRINT "REMOVING DOS, MASTER CREATE COULD WRITE": PRINT "OVER PARTS OF THEM!!!!": PRINT : INPUT "PRESS RETURN ";A$
  20. 200  HOME : PRINT "     TO INSTALL NOBOOT ON THE DISKETTE ": PRINT "IN ";: INVERSE : PRINT "SLOT 6, DRIVE 1";: NORMAL : PRINT " PRESS '@' (SHIFT P)."
  21. 210  PRINT : PRINT "     TO EXIT THE PROGRAM PRESS 'ESC'."
  22. 220  PRINT : PRINT "=->";: GET A$: PRINT A$: PRINT 
  23. 230  IF A$ =  CHR$(27)  THEN  HOME : END 
  24. 240  IF A$ = "@"  THEN 280
  25. 250  GOTO 200
  26. 260  END 
  27. 270 X = (42 - LEN(A$))/2: HTAB X: PRINT A$: RETURN 
  28. 280  FOR I = 8192 TO 8242: READ A: POKE I,A: NEXT I
  29. 290  DATA  0,173,232,192,169,240,133,54,169,253,133,55,32,88,252,32,221,251,169,0,141,5,3,172,5,3,185,51,8,32,237,253,238,5,3,173,5,3,201,96,240,3,76,23,8,32,27,253,76,0,198
  30. 300 AA$ = "THIS DISKETTE DOES NOT HAVE DOS ON IT"
  31. 310 BB$ = "PLACE THE SYSTEM DISKETTE IN DRIVE #1"
  32. 320 CC$ = "AND PRESS <RETURN>"
  33. 330 DD$ = "        "
  34. 340 EE$ = AA$ + CHR$(13) +BB$ + CHR$(13) +CC$ + CHR$(13) +DD$
  35. 350  FOR I = 1 TO  LEN(EE$)
  36. 360 NU =  ASC( MID$ (EE$,I,1)) +128
  37. 370  POKE 8243 +I -1,NU
  38. 380  NEXT I
  39. 390  FOR X = 12288 TO 12323: READ Y: POKE X,Y: NEXT X
  40. 400  DATA  169,48,160,10,32,217,3,96,0,0,1,96,1,0,0,0,32,48,0,32,0,0,2,0,0,96,1,0,0,0,0,0,0,1,239,216
  41. 410  CALL 12288
  42. 420  HOME :A$ = "NOBOOT IS INSTALLED": GOSUB 270: VTAB 23: END